Expresiones y declaraciones CASE en Oracle

La expresión CASE se agregó por primera vez a SQL en Oracle 8i. Desde entonces Oracle ha extendió su soporte a PL/SQL para permitir que CASE se use como expresión o declaración.

• Expresión CASE de coincidencia de valor (simple)
• Expresión CASE buscada
• Declaración CASE de coincidencia de valor (simple)
• Declaración CASE buscada

Expresión CASE de coincidencia de valor (simple)

La expresión CASE es como una versión más flexible de la función DECODE. La expresión CASE de coincidencia de valor, o expresión CASE simple, compara el valor de la expresión (DEPTNO) con la lista de expresiones de comparación (10 – 40). Una vez que encuentra una coincidencia, se devuelve el valor asociado. La cláusula ELSE opcional le permite tratar situaciones en las que no se encuentra una coincidencia. Observe que la expresión CASE tiene un alias como «departamento». Esto aparecerá como el nombre de la columna.

SELECT ename, empno, deptno,
  (CASE deptno
     WHEN 10 THEN 'Accounting'
     WHEN 20 THEN 'Research'
     WHEN 30 THEN 'Sales'
     WHEN 40 THEN 'Operations'
     ELSE 'Unknown'
   END) department
FROM emp
ORDER BY ename;

La expresión CASE de coincidencia de valor también se admite en PL/SQL. El siguiente ejemplo lo usa en una tarea.

SET SERVEROUTPUT ON
DECLARE
  deptno     NUMBER := 20;
  dept_desc  VARCHAR2(20);
BEGIN 
  dept_desc := CASE deptno
                 WHEN 10 THEN 'Accounting'
                 WHEN 20 THEN 'Research'
                 WHEN 30 THEN 'Sales'
                 WHEN 40 THEN 'Operations'
                 ELSE 'Unknown'
               END;
  DBMS_OUTPUT.PUT_LINE(dept_desc);
END;
/

Todos los valores posibles devueltos por una expresión CASE deben ser del mismo tipo de datos.

Expresión CASE buscada

La expresión CASE buscada puede ser más complicada, ya que implica varias columnas en las comparaciones. Cada comparación se prueba a su vez y se devuelve el valor asociado si se encuentra una coincidencia. Una vez más, existe una cláusula ELSE opcional para tratar situaciones en las que no se encuentra una coincidencia.

SELECT ename, empno, sal,
  (CASE
     WHEN sal < 1000 THEN 'Low' 
     WHEN sal BETWEEN 1000 AND 3000 THEN 'Medium' 
     WHEN sal > 3000 THEN 'High'
     ELSE 'N/A'
  END) salary
FROM emp
ORDER BY ename;

La expresión CASE buscada también se admite en PL/SQL.

SET SERVEROUTPUT ON
DECLARE
  sal       NUMBER := 2000;
  sal_desc  VARCHAR2(20);
BEGIN 
  sal_desc := CASE
                 WHEN sal < 1000 THEN 'Low' 
                 WHEN sal BETWEEN 1000 AND 3000 THEN 'Medium' 
                 WHEN sal > 3000 THEN 'High'
                 ELSE 'N/A'
              END;
  DBMS_OUTPUT.PUT_LINE(sal_desc);
END;
/

Todos los valores posibles devueltos por una expresión CASE deben ser del mismo tipo de datos.

Declaración CASE de coincidencia de valor (simple)

Las declaraciones CASE soportadas por PL/SQL son muy similares a las expresiones CASE. Observe que la declaración termina con las palabras clave END CASE en lugar de solo la palabra clave END. Las sentencias PL/SQL CASE son esencialmente una alternativa a las sentencias IF .. THEN .. ELSIF. Son estructuras de control que llaman condicionalmente bloques de código.

La declaración CASE de coincidencia de valor a continuación ejecuta un bloque de código diferente según la coincidencia encontrada.

SET SERVEROUTPUT ON
BEGIN
  FOR cur_rec IN (SELECT ename, empno, deptno FROM emp ORDER BY ename) LOOP
    DBMS_OUTPUT.PUT(cur_rec.ename || ' : ' || cur_rec.empno || ' : ' || cur_rec.deptno || ' : ');
    CASE cur_rec.deptno
      WHEN 10 THEN 
        DBMS_OUTPUT.PUT_LINE('Accounting');
      WHEN 20 THEN 
        DBMS_OUTPUT.PUT_LINE('Research');
      WHEN 30 THEN 
        DBMS_OUTPUT.PUT_LINE('Sales');
      WHEN 40 THEN 
        DBMS_OUTPUT.PUT_LINE('Operations');
      ELSE 
        DBMS_OUTPUT.PUT_LINE('Unknown');
    END CASE;
  END LOOP;
END;
/

Declaración CASE buscada

Al igual que con su contraparte de expresión, la instrucción CASE buscada permite múltiples comparaciones utilizando múltiples variables.

SET SERVEROUTPUT ON
BEGIN
  FOR cur_rec IN (SELECT ename, empno, sal FROM emp ORDER BY ename) LOOP
    DBMS_OUTPUT.PUT(cur_rec.ename || ' : ' || cur_rec.empno || ' : ' || cur_rec.sal || ' : ');
    CASE
      WHEN cur_rec.sal < 1000 THEN 
           DBMS_OUTPUT.PUT_LINE('Low'); 
      WHEN cur_rec.sal BETWEEN 1000 AND 3000 THEN 
           DBMS_OUTPUT.PUT_LINE('Medium'); 
      WHEN cur_rec.sal > 3000 THEN 
           DBMS_OUTPUT.PUT_LINE('High');
      ELSE 
           DBMS_OUTPUT.PUT_LINE('Unknown');
    END CASE;
  END LOOP;
END;
/

• Oracle9iSQL Reference Release 2 (9.2) : SQL CASE Expression
• PL/SQL User’s Guide and Reference Release 2 (9.2) : PL/SQL CASE Expression
• PL/SQL User’s Guide and Reference Release 2 (9.2) : PL/SQL CASE Statement